>>SOURCE FORMAT IS FIXED
      *>****************************************************************
      *>Author:    Brian Tiffin     
      *>Date:      11-Sep-2008 
      *>Purpose:   Embed some javascript 
      *>Tectonics: cobc -c -I/usr/include/smjs ocjs.c
      *>           cobc -x -l/smjs jscaller.cob ocjs.o 
      *>****************************************************************
       identification division.
       program-id. jscaller.

       data division.

       working-storage section.
       78 ocjs-error-runtime  value -1.
       78 ocjs-error-context  value -2.
       78 ocjs-error-global   value -3.
       78 ocjs-error-standard value -4.
       78 ocjs-error-evaluate value -5.

       78 newline              value x"0a".
       01 source-data          pic x(40)
            value "----+----1----+-$56.78 90----3----+----4".
       01 result               pic s9(9).
       01 result-field         pic x(81).

       01 javascript           pic x(1024).
       01 safety-null          pic x value x"00".

      *>****************************************************************
      *> Evaluate spidermonkey code, return the length of js result
       procedure division.

       display "js> " with no advancing end-display
       accept javascript end-accept
       call "ocjsString" 
           using javascript
               result-field
               by value function length(result-field)
           returning result
       end-call
       display "OpenCOBOL result-field: " result-field end-display
       display "OpenCOBOL recieved    : " result newline end-display

      *> Initialize the javascript engine
       call "ocjsInitialize"
           using by value 65536
               by value 1024
           returning result
       end-call
       if result less 0
           stop run returning result
       end-if

      *> find (zero offest) dollar amount, space, number
       move spaces to javascript
       string 
           "pat = /\$\d+\.\d+\s\d+/; "
           'a = "' delimited by size
           source-data delimited by size
           '"; ' delimited by size 
           "a.search(pat); " delimited by size
           x"00" delimited by size
           into javascript
       end-string

       display
           "Script: " function trim(javascript, trailing)
       end-display

       call "ocjsEvaluate"
           using javascript
               result-field
               by value function length(result-field)
           returning result
       end-call
       display "OpenCOBOL result-field: " result-field end-display
       display "OpenCOBOL recieved    : " result newline end-display

      *> values held in js engine across calls
       move spaces to javascript
       string 
           'a;' delimited by size
           x"00" delimited by size
           into javascript
       end-string

       display
           "Script: " function trim(javascript, trailing)
       end-display

       call "ocjsEvaluate"
           using javascript
               result-field
               by value function length(result-field)
           returning result
       end-call
       display "OpenCOBOL result-field: " result-field end-display
       display "OpenCOBOL recieved    : " result newline end-display

      *> erroneous script
       move spaces to javascript
       string 
           'an error of some kind;' delimited by size
           x"00" delimited by size
           into javascript
       end-string

       display
           "Script: " function trim(javascript, trailing)
       end-display

       call "ocjsEvaluate"
           using javascript
               result-field
               by value function length(result-field)
           returning result
       end-call
       if result equal ocjs-error-evaluate
           display " *** script problem ***" end-display
       end-if
       display "OpenCOBOL result-field: " result-field end-display
       display "OpenCOBOL recieved    : " result newline end-display

      *> script from file
       move spaces to javascript
       string 
           'ocjsscript.js' delimited by size
           x"00" delimited by size
           into javascript
       end-string

       display
           "Script: " function trim(javascript, trailing)
       end-display

       call "ocjsFromFile"
           using javascript
               result-field
               by value function length(result-field)
           returning result
       end-call
       if result equal ocjs-error-evaluate
           display " *** script problem ***" end-display
       end-if
       display "OpenCOBOL result-field: " result-field end-display
       display "OpenCOBOL recieved    : " result newline end-display

      *> Rundown the js engine
       call "ocjsRunDown" returning result 

      *> take first name last name, return last "," first
       move spaces to javascript
       string
           "re = /(\w+)\s(\w+)/; " delimited by size
           'str = "John Smith"; ' delimited by size
           'newstr = str.replace(re, "$2, $1"); ' delimited by size
           "newstr;" delimited by size
           x"00" delimited by size
           into javascript
       end-string

       display
           "Script: " function trim(javascript, trailing)
       end-display

       call "ocjsString"
           using javascript
               result-field
               by value function length(result-field)
           returning result
       end-call
       display "OpenCOBOL result-field: " result-field end-display
       display "OpenCOBOL recieved    : " result newline end-display

      *> split a string using numbers return array (as js string form)
       move spaces to javascript
       string
           'myString = "Hello 1 word. Sentence number 2."; '
               delimited by size
           'splits = myString.split(/(\d)/); ' delimited by size
           'splits;'  delimited by size
           x"00" delimited by size
           into javascript
       end-string

       display
           "Script: " function trim(javascript, trailing)
       end-display

       call "ocjsString"
           using javascript
               result-field
               by value function length(result-field)
           returning result
       end-call
       display "OpenCOBOL result-field: " result-field end-display
       display "OpenCOBOL recieved    : " result newline end-display

      *> Get javascript date
       move "new Date()" & x"00" to javascript

       display
           "Script: " function trim(javascript, trailing)
       end-display

       call "ocjsString"
           using javascript
               result-field
               by value function length(result-field)
           returning result
       end-call
       display "OpenCOBOL result-field: " result-field end-display
       display "OpenCOBOL recieved    : " result end-display

       goback.
       end program jscaller.